1.特快列车
2.老鸭回头
3.回抽支撑
4.一品低吸
5.短线快马
6.预测涨停板
7.空中加油
8.一品操盘+量能助手
9.均线拐点
10.一品种树
11.颠倒黑白
12.秘密买点
13.一品优化经典指标系列
14.领头羊
15.追影飞刀
16.突破回踩
17.鱼跃龙门
18.期待突破
19.一品快马
20.精准黑马
21.回升浪
22.一品量能MACD
23.涨跌音阶
24.三浪启动
25.黑马跟踪
26.一品爱家+经典震仓
27.金包银
28.一品心率
29.一品成本
30.经典震仓
31.短线三浪
32.平台突破
33.小箱体
34.大箱体
35.斜面推高
36.35秘密Z
37.一品MACD
38.简单KDJ
39.建仓拉升
40.阶段统计
41.简单F10
42.一品倍增Z
43.KD追涨
44.五线布林Z
45.MA20斜率
46.一品主力
47.放量攻击
48.热点五星
49.周期共振
50.个股强弱

[ 本帖最后由 蓝鼠 于 2008-5-2 10:32 编辑 ]

51.鸳鸯对
52.清澈见底
53.一品品股理念与选股方法
54.一品抄底
55.粘合出击
56.量能饱和
57.如何把握盘中的龙头与热点
58.走出峰谷
59.获利操盘
60.爱大波
61.急跌警报
62.暴涨暴跌
63.反向K线


[ 本帖最后由 蓝鼠 于 2008-5-27 08:04 编辑 ]

引用:

公式名称: 均线角度--【特快列车】
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-04-04
发表网址: http://www.li20.net/viewthread.php?tid=666901&highlight=

引用:

均线角度--【特快列车】(主副图通用原码)



一品指标，均线挖掘：三浪启动、短线三浪、回升浪、老鸭回头、登高望远、大（小）箱体……筹码集中：一品爱家；买点把握：一品心率、预测涨停板、平台突破、经典震仓……一个个指标，全部原码奉献，附加指标编写思路或使用方法，配图说明，无不在传达着一品选股理念与指标编写思路，相信大家从中应该能够得益一二。

股海无边，学无止境。牛市牛股不断，如何把握先机？上涨力度如何，能否判断选择？一品继续深思，尝试利用均线角度的变化，体现个股走势与上涨力度，名曰{特快列车}，提供主副图原码一套（通用），真诚希望各位朋友共同思考，不断研究、深化，一起乘上股市中的特快列车！

引用:

{特快列车Z----创幻论坛一品茶缘编写精品指标,大智慧主图}{通用}
{特快列车指标使用说明：
均线角度巧安排，要乘特快看站台；
买票上车是提示，启动加速列车开！}
A5:MA(C,5),COLOR00FFFF;
A20:MA(C,20),COLORFF00FF;
A30:MA(C,30),COLOR00FF00;
M5:=ATAN((A5/REF(A5,1)-1)*100)*180/3.14159;
M20:=ATAN((A20/REF(A20,1)-1)*100)*180/3.14159;
M30:=ATAN((A30/REF(A30,1)-1)*100)*180/3.14159;
QSXS:=M30>0;
A50:=IF(M5<0,-25,0);
A51:=IF(BETWEEN(M5,0,45),25,A50);
A52:=IF(BETWEEN(M5,45,75),50,A51);
MA5:=IF(M5>75,75,A52)*QSXS;
A200:=IF(M20<0,-25,0);
A201:=IF(BETWEEN(M20,0,45),25,A200);
A202:=IF(BETWEEN(M20,45,75),50,A201);
MA20:=IF(M20>75,75,A202)*QSXS;
A300:=IF(M30<0,-25,0);
A301:=IF(BETWEEN(M30,0,45),25,A300);
A302:=IF(BETWEEN(M30,45,75),50,A301);
MA30:=IF(M30>75,75,A302)*QSXS;
SGSJ:=BARSLAST(CROSS(MA5,REF(MA5+1,1)));
XGSJ:=BARSLAST(CROSS(REF(MA5-1,1),MA5));
列车:=IF(MA5>=50 AND MA20>=25 AND MA30>=25 AND SGSJ<XGSJ,50,25);
启动:=IF(CROSS(列车,45),50,25);
站台:=IF(MA5<=0 AND COUNT(MA20>=25,10)>=9 AND MA30>=25,-25,25);
买票:=IF(站台=-25 AND COUNT(站台=-25,3)>=2 AND C>=REF(C,4),25,-10);
上车:=IF(CROSS(MA5,0) AND COUNT(MA20>=25,10)>=9 AND MA30>=25,50,25);
{以下设置主图显示方式}
STICKLINE(MA20>0,A20,(A20+A30)/2,4,1),COLORFF00FF;
STICKLINE(MA30>0,A30,(A20+A30)/2,4,1),COLOR00FF00;
STICKLINE(MA5>0,A30,(A30*0.75+A20*0.25),4,1),COLOR00FFFF;
{追求简洁者,以上三行可删除.}
DRAWTEXT(列车=50,A30, '○'),COLOR88FFFF;
DRAWTEXT(启动=50,A30, '●'),COLORFF00FF;
STICKLINE(站台=-25,A30,A30*0.98,4,0),COLORFFFF00;
STICKLINE(买票=25,A30,A30*0.98,2,0),COLORFFFFFF;
DRAWTEXT(买票=25,A30*0.97, '票'),COLORFF8800;
DRAWTEXT(上车=50,A30, '△'),COLORFFFFFF;

引用:

{一品【特快列车】----创幻论坛一品茶缘编写精品指标,大智慧副图}{通用}
{特快列车指标使用说明：
均线角度巧安排，要乘特快看站台；
买票上车是提示，启动加速列车开！}
A5:=MA(C,5);
A20:=MA(C,20);
A30:=MA(C,30);
M5:=ATAN((A5/REF(A5,1)-1)*100)*180/3.14159;
M20:=ATAN((A20/REF(A20,1)-1)*100)*180/3.14159;
M30:=ATAN((A30/REF(A30,1)-1)*100)*180/3.14159;
QSXS:=M30>0;
A50:=IF(M5<0,-25,0);
A51:=IF(BETWEEN(M5,0,45),25,A50);
A52:=IF(BETWEEN(M5,45,75),50,A51);
MA5:IF(M5>75,75,A52)*QSXS,COLOR00FFFF;
A200:=IF(M20<0,-25,0);
A201:=IF(BETWEEN(M20,0,45),25,A200);
A202:=IF(BETWEEN(M20,45,75),50,A201);
MA20:IF(M20>75,75,A202)*QSXS,COLORFF00FF;
A300:=IF(M30<0,-25,0);
A301:=IF(BETWEEN(M30,0,45),25,A300);
A302:=IF(BETWEEN(M30,45,75),50,A301);
MA30:IF(M30>75,75,A302)*QSXS,COLOR00FF00;
SGSJ:=BARSLAST(CROSS(MA5,REF(MA5+1,1)));
XGSJ:=BARSLAST(CROSS(REF(MA5-1,1),MA5));
列车:IF(MA5>=50 AND MA20>=25 AND MA30>=25 AND SGSJ<XGSJ,50,25),COLOR00FFFF;
启动:IF(CROSS(列车,45),50,25),COLORFF00FF;
站台:IF(MA5<=0 AND COUNT(MA20>=25,10)>=9 AND MA30>=25,-25,25),COLORFFFF00;
买票:IF(站台=-25 AND COUNT(站台=-25,3)>=2 AND C>=REF(C,4),25,-10),COLORFF8800;
上车:IF(CROSS(MA5,0) AND COUNT(MA20>=25,10)>=9 AND MA30>=25,50,25),COLORFFFFFF;
{以下设置副图显示方式}
STICKLINE(MA5>0,25,33,4,1),COLOR00FFFF;
STICKLINE(MA20>0,33,41,4,1),COLORFF00FF;
STICKLINE(MA30>0,41,50,4,1),COLOR00FF00;
{追求简洁者,以上三行可删除.}
DRAWTEXT(列车=50,25, '○'),COLOR88FFFF;
DRAWTEXT(启动=50,25, '●'),COLORFF00FF;
DRAWTEXT(上车=50,25, '△'),COLORFFFFFF;
STICKLINE(站台=-25,-10,-25,4,0),COLORFFFF00;

[ 本帖最后由 蓝鼠 于 2008-3-20 11:53 编辑 ]

引用:

公式名称: 老鸭回头
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-01-10
发表网址: http://www.li20.net/viewthread.php?tid=602242&highlight=

引用:

一品大礼----{老鸭回头}主副图（原码）



一品近日有幸得到创幻各位前辈的厚爱，在大家的支持与关心中愧任创幻指标公式区版主，无以回报，唯有尽心尽力与指标公式区以及创幻的所有朋友携手共进，创造创幻更加美好、和谐的家园！现仅以唐能通《短线是银》一书提供的理念，精心编写适应牛市行情的{老鸭回头}精品指标，作为一品的一份礼物，奉献给有缘的朋友！

引用:

指标编写思路与信号含义：（类似{一品回升浪}）
1、老鸭回头=中线趋势向上+短线回头；
2、坑=短线超跌，白色特别超跌；
3、买=中线趋势向上+均线粘合+短线回升；
4、优选=买+10日、20日均线通道保持向上通畅；
5、逃顶=短线卖点，中线只做参考；

指标使用方法：
老鸭回头要关注，敢买深坑是高手；均线拐点是买点，通道顺畅应优选。

引用:

{老鸭回头Z----创幻论坛一品茶缘编写精品指标!大智慧主图}{飞狐通用}
{N:1,20,10;}
MA5:MA(C,5),COLORWHITE;
MA10:MA(C,10),COLORFF00FF;
MA20:MA(C,20),COLOR00FF00;
MA30:MA(C,30),COLORYELLOW;
MA120:SMA(C,120,1),COLOR0000FF;
ZH520:=ABS(MA5-MA20)/MA20*100<=N;
ZH530:=ABS(MA5-MA30)/MA30*100<=N;
QSXS1:=MA5>REF(MA5,1);
QSXS2:=MA20>REF(MA20,1);
QSXS3:=MA30>REF(MA30,1);
DTPL:=MA20>MA30 AND MA30>MA120;
LYHT:=DTPL AND QSXS2 AND QSXS3 AND NOT(QSXS1) AND REF(QSXS1,1);
老鸭回头:LYHT*50,COLORFF00FF,POINTDOT,LINETHICK0;
WR5:=100*(HHV(H,5)-C)/(HHV(H,5)-LLV(L,5));
WR6:=100*(HHV(H,6)-C)/(HHV(H,6)-LLV(L,6));
WR:=80-(WR5*3+WR6*2)/5,COLORYELLOW,POINTDOT;
坑:IF(WR<0,WR,0),COLORYELLOW,POINTDOT,LINETHICK0;
LYT:=DTPL AND QSXS2 AND QSXS3 AND COUNT(QSXS1,4)<=1;
GJHS:=C>MA5 AND ((QSXS1 AND NOT(REF(QSXS1,1))) OR C>REF(C,3));
LYKK:=GJHS AND (ZH520 OR ZH530) AND LYT;
买:(LYKK AND NOT(REF(LYKK,1)))*50,COLOR00FF00,POINTDOT,LINETHICK0;
优选:(买 AND COUNT((MA10>MA20),5)=5)*100,COLORYELLOW,POINTDOT,LINETHICK0;
{以下设置主图显示方式}
DRAWTEXT(老鸭回头,(MA10+MA20)/2, '●'),COLORFF00FF;
DRAWTEXT(老鸭回头,(MA10+MA20)/2, '¤'),COLORFF00FF;
DRAWTEXT(WR<0,L*0.99, '#'),COLORYELLOW;
DRAWTEXT(WR<-10,L*0.99, '#'),COLORWHITE;
STICKLINE(买,h,l,0,1),COLOR00FF00,linethick2;
STICKLINE(买,o,c,4,1),COLOR00FF00,linethick2;
DRAWTEXT(买,L*0.99, '买★买'),COLOR00FF00;
DRAWICON(优选,L*0.99,1);
{以下设置逃顶指标}
varC:=SMA(MAX(C-REF(C,1),0),6,1)/SMA(ABS(C-REF(C,1)),6,1)*100;
DRAWICON(CROSS(82,varC),HIGH,2);
var6:=REF(C,1);
var7:=SMA(MAX(C-var6,0),6,1)/SMA(ABS(C-var6),6,1)*100;
DRAWTEXT(CROSS(84,var7),H*1.01,'逃顶'),COLORYELLOW ;

引用:

{老鸭回头----创幻论坛一品茶缘编写精品指标!大智慧副图}{飞狐通用}
{N:1,20,10;}
MA5:=MA(C,5),COLORWHITE;
MA10:=MA(C,10),COLORFF00FF;
MA20:=MA(C,20),COLOR00FF00;
MA30:=MA(C,30),COLORYELLOW;
MA120:=SMA(C,120,1),COLOR0000FF;
ZH520:=ABS(MA5-MA20)/MA20*100<=N;
ZH530:=ABS(MA5-MA30)/MA30*100<=N;
QSXS1:=MA5>REF(MA5,1);
QSXS2:=MA20>REF(MA20,1);
QSXS3:=MA30>REF(MA30,1);
DTPL:=MA20>MA30 AND MA30>MA120;
LYHT:=DTPL AND QSXS2 AND QSXS3 AND NOT(QSXS1) AND REF(QSXS1,1);
老鸭回头:LYHT*50,COLORFF00FF;
WR5:=100*(HHV(H,5)-C)/(HHV(H,5)-LLV(L,5));
WR6:=100*(HHV(H,6)-C)/(HHV(H,6)-LLV(L,6));
WR:=80-(WR5*3+WR6*2)/5;
坑:IF(WR<0,WR,0),COLORYELLOW;
LYT:=DTPL AND QSXS2 AND QSXS3 AND COUNT(QSXS1,4)<=1;
GJHS:=C>MA5 AND ((QSXS1 AND NOT(REF(QSXS1,1))) OR C>REF(C,3));
LYKK:=GJHS AND (ZH520 OR ZH530) AND LYT;
买:(LYKK AND NOT(REF(LYKK,1)))*50,COLOR00FF00,LINETHICK2;
优选:(买 AND COUNT((MA10>MA20),5)=5)*100,COLORYELLOW,LINETHICK2;
{以下设置副图显示方式}
DRAWTEXT(老鸭回头,10,'●'),COLORFF00FF;
DRAWTEXT(老鸭回头,10,'¤'),COLORFF00FF;
STICKLINE(WR<0,WR,0,2,0),COLORYELLOW;
STICKLINE(WR<-10,WR,-10,2,0),COLORWHITE;
DRAWTEXT(买,80,'买★买'),COLOR00FF00;
DRAWICON(优选,10,1);
{以下设置逃顶指标}
varC:=SMA(MAX(C-REF(C,1),0),6,1)/SMA(ABS(C-REF(C,1)),6,1)*100;
DRAWICON(CROSS(82,varC),80,2);
var6:=REF(C,1);
var7:=SMA(MAX(C-var6,0),6,1)/SMA(ABS(C-var6),6,1)*100;
DRAWTEXT(CROSS(84,var7),100,'逃顶'),COLORYELLOW ;

引用:

公式名称: 回抽支撑
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2006-11-15
发表网址: http://www.li20.net/viewthread.php?tid=563782&highlight=

引用:

安心操作----{回抽支撑}主副图奉送【优化原码】



大盘大幅震荡，赚钱不易亏损快。股市心态浮沉，追涨易套，买跌无底，能否寻找一个安全操作的定心丸？一品深思，不断探索，继{一品自选}追涨操作之后，经过两周默默深思、优化、修改之后，初步完成安全操作、低买指标{回抽支撑}主副图一套。因前期一品指标在未成熟之下已经被随意转帖，故先加密奉送，并附指标编写思路与使用技巧，加图说明，以免误友误己。欢迎大家试用，提出优化参考意见，确定基本成熟之后，将在本帖原码公开！

引用:

精品指标{回抽支撑----一品茶缘编写，大智慧主、副图一套}{飞狐通用}
指标编写思路：
1、趋势向上：支撑均线保持向上，安全操作；
2、多头排列：均线系统成多头发散排列，形成上级保障；
3、站稳均线：股价连续站在指定均线之上达到一定日期；
4、回抽均线：股价在满足1、2、3的基础上，最低价或者收盘价回靠、下穿某均线，视为回抽；
5、买点确定：当股价回抽均线距离在2%之内，确定为回抽买点。

指标信号与使用技巧：
1、指标信号：回抽均线，分别以同颜色的数字⊙②③④⑤⑥，在该均线位置表示；
2、短期优选：短期均线的回抽信号越有价值；
3、首次优选：同一均线的回抽买点信号，短期内首次出现优选；再次出现选择放弃，关注下一均线支撑买点；
4、多头优选：均线多头排列越顺畅的优选；
5、买点把握：买点设定为回抽均线，故盘中买点最好买在盘中股价打到均线+-2%附近时，盘中明显下跌动能有所减弱时及时跟进，---注意尽量买在均线附近，盘中切记不可追涨！
6、获利把握：买点后三日，一般应有反弹行情出现；如短期已经有明显回抽买点与反弹波段出现，此时的回抽也许会变成破位走弱，应该适当回避。

引用:

{回抽支撑----一品茶缘编写，弱市专用！大智慧副图指标}{飞狐通用}
{优选思路：短线趋势向上+连续缩量+WR指标超跌}
{短线交易--威连指标参考}
WR1:=100*(HHV(HIGH,10)-CLOSE)/(HHV(HIGH,10)-LLV(LOW,10));
WR2:=100*(HHV(HIGH,6)-CLOSE)/(HHV(HIGH,6)-LLV(LOW,6));
涨:WR2<10,POINTDOT,COLORRED;
跌:WR2>80,POINTDOT,COLORWHITE;
DRAWTEXT(涨>0 ,7 , '$'),COLORRED;
DRAWTEXT(跌>0 ,1 , '#'),COLORWHITE;
P1:=5;P2:=10;P3:=20;P4:=30;P5:=60;P6:=120;
MA1:=MA(C,P1),COLORYELLOW;
MA2:=MA(C,P2),COLORFF00FF;
MA3:=MA(C,P3),COLOR00FF00;
MA4:=MA(C,P4),COLORWHITE;
MA5:=MA(C,P5),COLORFF9900;
MA6:=MA(C,P6),COLOR0000FF;
{ENV轨道线支撑}
UPPER:=(1+6/100)*MA(CLOSE,25);
LOWER:=(1-6/100)*MA(CLOSE,25);
MID:=(UPPER+LOWER)/2,COLORYELLOW,LINETHICK2;
生命线:=MID,COLORYELLOW,POINTDOT,LINETHICK2;
DTPLENV:=COUNT(MID>REF(MID,1),5)=5;
回:=((CROSS(MID,L) OR CROSS(MID,C)) AND DTPLENV)*1,COLORYELLOW,POINTDOT;
{MA2支撑}
QSXS2:=MA2>=REF(MA2,1);
DTPL2:=MA1>MA2 AND MA2>MA3 AND MA3>MA4;
ZWP2:=COUNT(C>MA2,P1)=P1 AND DTPL2;
HCP2A:=CROSS(MA2*1.02,L) AND REF(ZWP2,1);
HCP2B:=CROSS(MA2,C) AND REF(ZWP2,1);
回2:=((HCP2A OR HCP2B) AND QSXS2 AND DTPL2)*3,COLOR00FF00,POINTDOT;
{MA3支撑}
QSXS3:=MA3>=REF(MA3,1);
DTPL3:=MA1>MA2 AND MA2>MA3 AND MA3>MA4;
ZWP3:=COUNT(C>MA3,P1)=P1 AND DTPL3;
HCP3A:=CROSS(MA3*1.03,L) AND REF(ZWP3,1);
HCP3B:=CROSS(MA3,C) AND REF(ZWP3,1);
回3:=((HCP3A OR HCP3B) AND QSXS3)*3,COLOR00FF00,POINTDOT;
{MA4支撑}
QSXS4:=MA4>=REF(MA4,1);
DTPL4:=MA2>MA3 AND MA3>MA4 AND MA4>MA5;
ZWP4:=COUNT(C>MA4,P2)=P2 AND DTPL4;
HCP4A:=CROSS(MA4*1.04,L) AND REF(ZWP4,1);
HCP4B:=CROSS(MA4*1.02,C) AND REF(ZWP4,1);
回4:=((HCP4A OR HCP4B) AND QSXS4)*4,COLORWHITE,POINTDOT;
{MA5支撑}
QSXS5:=MA5>=REF(MA5,1);
DTPL5:=MA3>MA4 AND MA4>MA5 AND MA5>MA6;
ZWP5:=COUNT(C>MA5,P3)=P3 AND DTPL5;
HCP5A:=CROSS(MA5*1.05,L) AND REF(ZWP5,1);
HCP5B:=CROSS(MA5*1.02,C) AND REF(ZWP5,1);
回5:=((HCP5A OR HCP5B) AND QSXS5)*5,COLORFF9900,POINTDOT;
{MA6支撑}
QSXS6:=MA6>=REF(MA6,1);
DTPL6:=MA5>MA6;
ZWP6:=COUNT(C>MA6,P3)=P3 AND DTPL6;
HCP6A:=CROSS(MA6*1.05,L) AND REF(ZWP6,1);
HCP6B:=CROSS(MA6*1.02,C) AND REF(ZWP6,1);
回6:=((HCP6A OR HCP6B) AND QSXS6)*6,COLORRED,POINTDOT;
买:COUNT(回>0,2)>=1 AND ABS(L/MID-1)*100<=2,COLORYELLOW,POINTDOT;
买2:COUNT(回2>0,2)>=1 AND ABS(L/MA2-1)*100<=2,COLORFF00FF,POINTDOT;
买3:COUNT(回3>0,2)>=1 AND ABS(L/MA3-1)*100<=2,COLOR00FF00,POINTDOT;
买4:COUNT(回4>0,2)>=1 AND ABS(L/MA4-1)*100<=2,COLORWHITE,POINTDOT;
买5:COUNT(回5>0,2)>=1 AND ABS(L/MA5-1)*100<=2,COLORFF9900,POINTDOT;
买6:COUNT(回6>0,2)>=1 AND ABS(L/MA6-1)*100<=2,COLORRED,POINTDOT;
MBZ:=买 OR 买2 OR 买3 OR 买4 OR 买5 OR 买6;
QSXS:=DTPL4 AND MA3>REF(MA3,1) AND MA4>REF(MA4,1);
YX:=跌 AND MBZ AND QSXS AND COUNT(V<REF(V,1),4)>=2 AND COUNT(C<REF(C,1),3)>=2;
优选:(YX OR (REF(YX,1) AND C<REF(C,1)))*5,COLOR00FF00;
{以下设置副图显示方式}
1,POINTDOT,COLORYELLOW;
2,POINTDOT,COLORFF00FF;
3,POINTDOT,COLOR00FF00;
4,POINTDOT,COLORWHITE;
5,POINTDOT,COLORFF9900;
6,POINTDOT,COLORRED;
7,POINTDOT,color00FF00;
STICKLINE(买>0,1,2,4,0),COLORYELLOW;
STICKLINE(买2>0,2,3,4,0),COLORFF00FF;
STICKLINE(买3>0,3,4,4,0),COLOR00FF00;
STICKLINE(买4>0,4,5,4,0),COLORWHITE;
STICKLINE(买5>0,5,6,4,0),COLORFF9900;
STICKLINE(买6>0,6,7,4,0),COLORRED;
DRAWTEXT(回>0 ,1 , '⊙'),COLORYELLOW;
DRAWTEXT(回2>0 ,2 , '②'),COLORFF00FF;
DRAWTEXT(回3>0 ,3 , '③'),COLOR00FF00;
DRAWTEXT(回4>0 ,4 , '④'),COLORWHITE;
DRAWTEXT(回5>0 ,5 , '⑤'),COLORFF9900;
DRAWTEXT(回6>0 ,6 , '⑥'),COLORRED;
{以下设置主图显示方式}
{DRAWTEXT(回>0 ,MID , '⊙'),COLORYELLOW;
DRAWTEXT(回2>0 ,MA2 , '②'),COLORFF00FF;
DRAWTEXT(回3>0 ,MA3 , '③'),COLOR00FF00;
DRAWTEXT(回4>0 ,MA4 , '④'),COLORWHITE;
DRAWTEXT(回5>0 ,MA5 , '⑤'),COLORFF9900;
DRAWTEXT(回6>0 ,MA6 , '⑥'),COLORRED;
DRAWTEXT(买>0 ,L*0.99 , '★'),COLORYELLOW;
DRAWTEXT(买2>0 ,L*0.98 , '□'),COLORFF00FF;
DRAWTEXT(买3>0 ,L*0.99 , '▲'),COLOR00FF00;
DRAWTEXT(买4>0 ,L*0.98 , '◆'),COLORWHITE;
DRAWTEXT(买5>0 ,L*0.99 , '■'),COLORFF9900;
DRAWTEXT(买6>0 ,L*0.98 , '●'),COLORRED;
支撑点:IF(COUNT(ZC3>0,5),REF(L,HCSJ3),REF(L,HCSJ3)),COLOR00FF00,POINTDOT,linethick1;}

引用:

{回抽支撑Z----一品茶缘编写，弱市专用！大智慧主图指标}{飞狐通用}
{优选思路：短线趋势向上+连续缩量+WR指标超跌}
{短线交易--威连指标参考}
WR1:=100*(HHV(HIGH,10)-CLOSE)/(HHV(HIGH,10)-LLV(LOW,10));
WR2:=100*(HHV(HIGH,6)-CLOSE)/(HHV(HIGH,6)-LLV(LOW,6));
涨:=WR2<10,POINTDOT,COLORRED;
跌:=WR2>80,POINTDOT,COLORWHITE;
DRAWTEXT(涨>0 ,H*1.02 , '$'),COLORRED;
DRAWTEXT(跌>0 ,L*0.98 , '#'),COLORWHITE;
P1:=5;P2:=10;P3:=20;P4:=30;P5:=60;P6:=120;
MA1:MA(C,P1),COLORYELLOW;
MA2:MA(C,P2),COLORFF00FF;
MA3:MA(C,P3),COLOR00FF00;
MA4:MA(C,P4),COLORWHITE;
MA5:MA(C,P5),COLORFF9900;
MA6:MA(C,P6),COLOR0000FF;
{ENV轨道线支撑}
UPPER:=(1+6/100)*MA(CLOSE,25);
LOWER:=(1-6/100)*MA(CLOSE,25);
MID:=(UPPER+LOWER)/2,COLORYELLOW,LINETHICK2;
生命线:MID,COLORYELLOW,POINTDOT,LINETHICK2;
DTPLENV:=COUNT(MID>REF(MID,1),5)=5;
回:=((CROSS(MID,L) OR CROSS(MID,C)) AND DTPLENV)*1,COLORYELLOW,POINTDOT;
{MA2支撑}
QSXS2:=MA2>=REF(MA2,1);
DTPL2:=MA1>MA2 AND MA2>MA3 AND MA3>MA4;
ZWP2:=COUNT(C>MA2,P1)=P1 AND DTPL2;
HCP2A:=CROSS(MA2*1.02,L) AND REF(ZWP2,1);
HCP2B:=CROSS(MA2,C) AND REF(ZWP2,1);
回2:=((HCP2A OR HCP2B) AND QSXS2 AND DTPL2)*3,COLOR00FF00,POINTDOT;
{MA3支撑}
QSXS3:=MA3>=REF(MA3,1);
DTPL3:=MA1>MA2 AND MA2>MA3 AND MA3>MA4;
ZWP3:=COUNT(C>MA3,P1)=P1 AND DTPL3;
HCP3A:=CROSS(MA3*1.03,L) AND REF(ZWP3,1);
HCP3B:=CROSS(MA3,C) AND REF(ZWP3,1);
回3:=((HCP3A OR HCP3B) AND QSXS3)*3,COLOR00FF00,POINTDOT;
{MA4支撑}
QSXS4:=MA4>=REF(MA4,1);
DTPL4:=MA2>MA3 AND MA3>MA4 AND MA4>MA5;
ZWP4:=COUNT(C>MA4,P2)=P2 AND DTPL4;
HCP4A:=CROSS(MA4*1.04,L) AND REF(ZWP4,1);
HCP4B:=CROSS(MA4*1.02,C) AND REF(ZWP4,1);
回4:=((HCP4A OR HCP4B) AND QSXS4)*4,COLORWHITE,POINTDOT;
{MA5支撑}
QSXS5:=MA5>=REF(MA5,1);
DTPL5:=MA3>MA4 AND MA4>MA5 AND MA5>MA6;
ZWP5:=COUNT(C>MA5,P3)=P3 AND DTPL5;
HCP5A:=CROSS(MA5*1.05,L) AND REF(ZWP5,1);
HCP5B:=CROSS(MA5*1.02,C) AND REF(ZWP5,1);
回5:=((HCP5A OR HCP5B) AND QSXS5)*5,COLORFF9900,POINTDOT;
{MA6支撑}
QSXS6:=MA6>=REF(MA6,1);
DTPL6:=MA5>MA6;
ZWP6:=COUNT(C>MA6,P3)=P3 AND DTPL6;
HCP6A:=CROSS(MA6*1.05,L) AND REF(ZWP6,1);
HCP6B:=CROSS(MA6*1.02,C) AND REF(ZWP6,1);
回6:=((HCP6A OR HCP6B) AND QSXS6)*6,COLORRED,POINTDOT;
买:=COUNT(回>0,2)>=1 AND ABS(L/MID-1)*100<=2,COLORYELLOW,POINTDOT;
买2:=COUNT(回2>0,2)>=1 AND ABS(L/MA2-1)*100<=2,COLORFF00FF,POINTDOT;
买3:=COUNT(回3>0,2)>=1 AND ABS(L/MA3-1)*100<=2,COLOR00FF00,POINTDOT;
买4:=COUNT(回4>0,2)>=1 AND ABS(L/MA4-1)*100<=2,COLORWHITE,POINTDOT;
买5:=COUNT(回5>0,2)>=1 AND ABS(L/MA5-1)*100<=2,COLORFF9900,POINTDOT;
买6:=COUNT(回6>0,2)>=1 AND ABS(L/MA6-1)*100<=2,COLORRED,POINTDOT;
MBZ:=买 OR 买2 OR 买3 OR 买4 OR 买5 OR 买6;
QSXS:=DTPL4 AND MA3>REF(MA3,1) AND MA4>REF(MA4,1);
YX:=跌 AND MBZ AND QSXS AND COUNT(V<REF(V,1),4)>=2 AND COUNT(C<REF(C,1),3)>=2;
优选:=(YX OR (REF(YX,1) AND C<REF(C,1)))*5,COLOR00FF00;
{以下设置副图显示方式}
{1,POINTDOT,COLORYELLOW;
2,POINTDOT,COLORFF00FF;
3,POINTDOT,COLOR00FF00;
4,POINTDOT,COLORWHITE;
5,POINTDOT,COLORFF9900;
6,POINTDOT,COLORRED;
7,POINTDOT,color00FF00;
STICKLINE(买>0,1,2,4,0),COLORYELLOW;
STICKLINE(买2>0,2,3,4,0),COLORFF00FF;
STICKLINE(买3>0,3,4,4,0),COLOR00FF00;
STICKLINE(买4>0,4,5,4,0),COLORWHITE;
STICKLINE(买5>0,5,6,4,0),COLORFF9900;
STICKLINE(买6>0,6,7,4,0),COLORRED;
DRAWTEXT(回>0 ,1 , '⊙'),COLORYELLOW;
DRAWTEXT(回2>0 ,2 , '②'),COLORFF00FF;
DRAWTEXT(回3>0 ,3 , '③'),COLOR00FF00;
DRAWTEXT(回4>0 ,4 , '④'),COLORWHITE;
DRAWTEXT(回5>0 ,5 , '⑤'),COLORFF9900;
DRAWTEXT(回6>0 ,6 , '⑥'),COLORRED;}
{以下设置主图显示方式}
DRAWTEXT(回>0 ,MID , '⊙'),COLORYELLOW;
DRAWTEXT(回2>0 ,MA2 , '②'),COLORFF00FF;
DRAWTEXT(回3>0 ,MA3 , '③'),COLOR00FF00;
DRAWTEXT(回4>0 ,MA4 , '④'),COLORWHITE;
DRAWTEXT(回5>0 ,MA5 , '⑤'),COLORFF9900;
DRAWTEXT(回6>0 ,MA6 , '⑥'),COLORRED;
DRAWTEXT(买>0 ,L*0.99 , '★'),COLORYELLOW;
DRAWTEXT(买2>0 ,L*0.98 , '□'),COLORFF00FF;
DRAWTEXT(买3>0 ,L*0.99 , '▲'),COLOR00FF00;
DRAWTEXT(买4>0 ,L*0.98 , '◆'),COLORWHITE;
DRAWTEXT(买5>0 ,L*0.99 , '■'),COLORFF9900;
DRAWTEXT(买6>0 ,L*0.98 , '●'),COLORRED;
DRAWTEXT(优选>0 ,L*0.97 , '优'),COLOR00FF00;
HCSJ3:=BARSLAST(回3);
ZC3:=(CROSS(C,MA3) OR CROSS(C,MA3*1.03)) AND HCSJ3<=5;
支撑点:IF(COUNT(ZC3>0,5),REF(L,HCSJ3),REF(L,HCSJ3)),COLOR00FF00,POINTDOT,linethick1;

引用:

公式名称: 一品低吸
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-01-01
发表网址: http://www.li20.net/viewthread.php?tid=596050&highlight=

引用:

元旦礼物----{一品低吸}（原码1-02修改）




龙头股的强劲拉升,确实令人羡慕,但是真正能够把握住的机会却不多;而龙头股短线出现连续下跌后的超跌反弹,能否成为我们补偿的一次机会呢?一品觉得可以作为一种低吸备选的选择----但是这个就需要选择超跌的短线功夫与心理考验了!
一品根据个人长期积累经验,分析龙头回调的K线组合,把握超跌幅度,编写{一品低吸----龙头超跌}指标,作为2007年的第一份小礼,供喜欢超跌的朋友一阅，欢迎大家批评！指标信号含义简单易解,一品就不必赘言了.

引用:

一品低吸----龙头超跌,一品茶缘编写,大智慧副图指标}{飞狐通用}

{DDF:10,30,18;}
龙:IF((C/REF(C,1)-1)*100>=5 AND C>O*1.04,20,0),COLORFF00FF,POINTDOT;
LTSJ:=BARSLAST(龙);
回头:IF(LTSJ<=13 AND L<REF(O,LTSJ) AND C/REF(C,1)<=0.98,10,0),COLORFF6600,POINTDOT,LINETHICK2;
LXXD:=COUNT(C<REF(C,1),4)>=3 OR COUNT(C<REF(C,1),5)>=4 OR COUNT(C<REF(C,1),6)>=5;
TDDF:=(HHV(H,5)/L-1)*100>DDF OR (HHV(H,7)/LOW-1)*100>DDF;
超跌:IF(LXXD AND TDDF AND C<=REF(C,1),20,0),COLORWHITE,LINETHICK2;
WR5:=100*(HHV(H,5)-C)/(HHV(H,5)-LLV(L,5));
WR6:=100*(HHV(H,6)-C)/(HHV(H,6)-LLV(L,6));
WR:=80-(WR5*3+WR6*2)/5;
坑:IF(WR<0,WR,0),COLORYELLOW;
低吸:IF((超跌 OR 回头) AND WR<-10,30,0),COLORFFFF99,LINETHICK2;
DXDT:=MA(CLOSE,5)>MA(CLOSE,30) AND MA(CLOSE,20)>MA(CLOSE,30);
优选:IF(超跌 AND WR<0 AND DXDT AND 回头,50,0),COLOR00FF00,LINETHICK2;
{以下设置副图显示方式}
STICKLINE(龙,0,20,4,0),COLORFF00FF;
STICKLINE(回头,0,10,2,0),COLORFF6600;
STICKLINE(WR<0,WR,0,2,0),COLORYELLOW;
STICKLINE(WR<-10,WR,-10,3,0),COLORWHITE;
DRAWTEXT(优选,45,'低◆买'),COLOR00FF00;
DRAWICON(优选,5,1);

引用:

公式名称: 短线快马
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2006-08-21
发表网址: http://www.li20.net/viewthread.php?tid=503493&highlight=

引用:

短线快马主图、副图{大智慧、飞狐通用}



说明：很少在论坛上发自己编写的指标,都是拿高手的了。最近看到不少朋友拿出了自己编写的好指标，因此将本人觉得较有参考价值的一个指标“短线快马”拿出来与大家共享，指标主要提供买入信号，附上详细编写思路。特别欢迎创幻的高手们针对指标编写思路与编写方法给予批评指正，也欢迎大家对该指标进行优化！

引用:

{短线快马副图----一品茶缘编写}
{1、线：股票短期均线5、10、20、30呈多头排列；获利盘达到60%左右，庄家筹码比较集中；
2、量：短期量能曾经连续萎缩3天；
3、价：短期股价曾经连跌3天，或者低点、高点或中心不断下移；
4、涨：今日出现第一根中阳线放量拉升，可以视为短线快马，一般次日均能再涨；
5、除：适当排除短线已经连续拉出阳线或已经具有较大涨幅个股；
6、回：短线快马该涨不涨，2日内连续缩量回调，可作为回调买点。}

{获利盘--庄家筹码集中度}
获利:=WINNER(CLOSE),COLORRED;
CMJZ:=CLOSE/COST(60)>0.98;
{短线多头}
DT1:=(CLOSE>REF(CLOSE,4) OR MA(CLOSE,5)>MA(CLOSE,10)) AND MA(CLOSE,10)>MA(CLOSE,20) AND MA(CLOSE,20)>MA(CLOSE,30);
DT2:=MA(CLOSE,5)>=REF(MA(CLOSE,5),1) AND MA(CLOSE,10)>REF(MA(CLOSE,10),1) AND MA(CLOSE,20)>REF(MA(CLOSE,20),1) AND MA(CLOSE,30)>REF(MA(CLOSE,30),1);
{量形波浪}
LXSL:=(VOL<REF(VOL,1) AND REF(VOL,1)<REF(VOL,2)) OR VOL<REF(VOL,1)/1.8;
SLSJ:=BARSLAST(LXSL);
{k线波浪}
GJZX:=(O+C+H+L)/4;
LXXD:=(C<REF(C,1) AND REF(C,1)<REF(C,2)) OR (GJZX<REF(GJZX,1) AND REF(GJZX,1)<REF(GJZX,2)) OR (H<REF(H,1) AND REF(H,1)<REF(H,2)) OR (L<REF(L,1) AND REF(L,1)<REF(L,2) AND GJZX<REF(GJZX,1));
XDSJ:=BARSLAST(LXXD);
QRSP:=REF(CLOSE,1)/REF(CLOSE,2)<=1.035;
LXSY:=(H/REF(CLOSE,1)>=1.05 AND REF(CLOSE,1)>REF(CLOSE,2)*1.02 AND REF(CLOSE,2)>=REF(CLOSE,3)*1.02) OR H/REF(CLOSE,3)>=1.15,COLORRED;
FLSZ:=VOL>REF(VOL,1)*1.5 AND VOL>MA(VOL,5) AND CLOSE/REF(CLOSE,1)>=1.02;
短线:(FLSZ AND SLSJ<=3 AND XDSJ<=3)*0.5,COLORFF6600,LINETHICK1;
快马:(CMJZ AND DT1 AND DT2 AND QRSP AND SLSJ<=6 AND XDSJ<=6 AND FLSZ AND LXSY=0)*1.5,COLORYELLOW,LINETHICK2;
drawicon((获利>0.6 and 快马>0),0.2,1);
DRAWTEXT(快马>0 ,0.8 , '马'),COLORRED,LINETHICK1;
ma0:=ma(c,5);
ma1:=ma(c,10);
穿:=(CROSS(C,MA0) OR (O<MA0 AND C>MA0)) AND V>REF(V,1) AND MA0>REF(MA0,1) AND MA1>REF(MA1,1);
DRAWTEXT(穿>0 ,1.8 , '穿'),COLORYELLOW,LINETHICK1;
{快马回头}
N4:=BARSLAST(短线 OR 快马);
HT1:=N4<=2 AND L>REF(L,N4) AND C/REF(C,N4)<1.015 AND V<REF(V,1);
HT2:=REF(HT1,1) AND (C<=REF(C,1) OR C<=REF(C,N4)) AND C>REF(O,N4) AND V<REF(V,1);
回头:HT2*0.8,COLORWHITE,STICK,LINETHICK2;
DRAWTEXT(回头>0 ,0.5 , '回'),COLORFF00FF,LINETHICK1;
QSXS:(MA(C,30)>REF(MA(C,30),1))*0.5, CIRCLEDOT,COLORYELLOW;

引用:

{短线快马主图----一品茶缘编写}
{1、线：股票短期均线5、10、20、30呈多头排列；获利盘达到60%左右，庄家筹码比较集中；
2、量：短期量能曾经连续萎缩3天；
3、价：短期股价曾经连跌3天，或者低点、高点或中心不断下移；
4、涨：今日出现第一根中阳线放量拉升，可以视为短线快马，一般次日均能再涨；
5、除：适当排除短线已经连续拉出阳线或已经具有较大涨幅个股；
6、回：短线快马该涨不涨，2日内连续缩量回调，可作为回调买点。}

MA5:MA(CLOSE,5),COLORWHITE,LINETHICK2;
MA30:MA(CLOSE,30),COLORYELLOW,LINETHICK2;

{获利盘--庄家筹码集中度}
获利:=WINNER(CLOSE),COLORRED;
CMJZ:=CLOSE/COST(60)>0.98;
{短线多头}
DT1:=(CLOSE>REF(CLOSE,4) OR MA(CLOSE,5)>MA(CLOSE,10)) AND MA(CLOSE,10)>MA(CLOSE,20) AND MA(CLOSE,20)>MA(CLOSE,30);
DT2:=MA(CLOSE,5)>=REF(MA(CLOSE,5),1) AND MA(CLOSE,10)>REF(MA(CLOSE,10),1) AND MA(CLOSE,20)>REF(MA(CLOSE,20),1) AND MA(CLOSE,30)>REF(MA(CLOSE,30),1);
{量形波浪}
LXSL:=(VOL<REF(VOL,1) AND REF(VOL,1)<REF(VOL,2)) OR VOL<REF(VOL,1)/1.8;
SLSJ:=BARSLAST(LXSL);
{k线波浪}
GJZX:=(O+C+H+L)/4;
LXXD:=(C<REF(C,1) AND REF(C,1)<REF(C,2)) OR (GJZX<REF(GJZX,1) AND REF(GJZX,1)<REF(GJZX,2)) OR (H<REF(H,1) AND REF(H,1)<REF(H,2)) OR (L<REF(L,1) AND REF(L,1)<REF(L,2) AND GJZX<REF(GJZX,1));
XDSJ:=BARSLAST(LXXD);
QRSP:=REF(CLOSE,1)<REF(CLOSE,2) OR REF(CLOSE,1)/REF(CLOSE,2)<=1.035;
LXSY:=(H/REF(CLOSE,1)>=1.05 AND REF(CLOSE,1)>REF(CLOSE,2)*1.02 AND REF(CLOSE,2)>=REF(CLOSE,3)*1.02) OR H/REF(CLOSE,3)>=1.15,COLORRED;
FLSZ:=VOL>REF(VOL,1)*1.5 AND VOL>MA(VOL,5) AND CLOSE/REF(CLOSE,1)>=1.02;
短:=(FLSZ AND SLSJ<=3 AND XDSJ<=3)*0.5,COLORFF6600,STICK,LINETHICK1;
DRAWTEXT(短>0 ,L*0.97 , '短'),COLORYELLOW,LINETHICK1;
马:=(CMJZ AND DT1 AND DT2 AND QRSP AND SLSJ<=6 AND XDSJ<=6 AND FLSZ AND LXSY=0)*1.5,COLORYELLOW,STICK,LINETHICK2;
drawicon((获利>0.6 and 马>0),l-0.02,1);
DRAWTEXT(马>0 ,L*0.99, '马'),COLORRED,LINETHICK1;
ma0:=ma(c,5);
ma1:=ma(c,10);
穿:=(CROSS(C,MA0) OR (O<MA0 AND C>MA0)) AND V>REF(V,1) AND MA0>REF(MA0,1) AND MA1>REF(MA1,1);
DRAWTEXT(穿>0 ,H*1.03, '穿'),COLORYELLOW,LINETHICK1;
{快马回头}
N4:=BARSLAST(短 OR 马);
HT1:=N4<=2 AND L>REF(L,N4) AND C/REF(C,N4)<1.015 AND V<REF(V,1);
HT2:=REF(HT1,1) AND (C<=REF(C,1) OR C<=REF(C,N4)) AND C>REF(O,N4) AND V<REF(V,1);
回:=HT2*0.8,COLORWHITE,STICK,LINETHICK2;
STICKLINE(回,L*0.98,L*0.92,0,1),colorwhite,linethick2;
DRAWTEXT(回>0 ,L*0.95 , '回'),COLORFF00FF,LINETHICK1;
STICKLINE(短 OR 马,h,l,0,1),colorYELLOW,linethick2;
STICKLINE(短 OR 马,o,c,4,1),colorYELLOW,linethick2;
QSXS:=(MA(C,30)>REF(MA(C,30),1))*REF(MA(C,30),1)-0.1, CIRCLEDOT,COLORYELLOW;
DRAWTEXT(QSXS>0 ,MA30-0.02 , '○'),coloryellow,LINETHICK1;

引用:

公式名称: 预测涨停板
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-02-04
发表网址: http://www.li20.net/viewthread.php?tid=621547&highlight=

引用:

预测涨停板（一品优化版）



近日，见创幻论坛指标{精确预测涨停板}指标，一品观察、思考，尾数WS数字何意？一品不解，选择放弃。（如有高人发现其中奥妙，欢迎指教！）剖析原码，原来是KDJ指标的变形：N=K+D（均取整数），但是思路还是满有创意的！一品喜欢，故继续思考，放弃尾数，加入目标价位（价）、涨幅跟踪（涨）、低吸设置（低），目标到位提示（达标，画红色柱），修改风险提示（比原指标基本提前发出），形成较完整的操作过程，更加便于参考。
说明：该指标为中线波段操作参考指标，短线不一定有效，请结合N线浪形、K线组合与中期趋势形态等适当参考。

引用:

{预测涨停板----创幻论坛一品茶缘优化版,大智慧副图}{通用}
{DF:3,10,5;DF表示涨停信号出现后的短期跌幅，低吸信号使用。}
{指标使用方法：
经典指标K D J ，适当优化成新宠；
中线参考价值大，奥妙尽在浪形中。
预测信号是启动，涨停价位十来送；
涨幅跟踪好低吸，高位风险应慎重。}
RSV:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
K:=(SMA(RSV,3,1));
D:=(SMA(K,3,1));
KK:=INTPART(SMA(RSV,3,1));
DD:=INTPART(SMA(K,3,1));
N:KK+DD,COLORff00ff,LINETHICK2;
预测:IF(CROSS(N,50),90,50),COLOR00FF00;
涨停:IF(CROSS(N,100),100,50),COLORYELLOW;
ZTSJ:=BARSLAST(涨停=100);
价:REF(C,ZTSJ)*1.1,COLOR0000FF,POINTDOT,LINETHICK0;
涨:(C/REF(C,ZTSJ)-1)*100,COLOR99FF00,LINETHICK1;
低:IF(ZTSJ>0 AND ZTSJ<10 AND (L/REF(C,ZTSJ)-1)*100<=-DF,5,50),COLORWHITE;
达标:=ZTSJ<20 AND CROSS(H,REF(C,ZTSJ)*1.1);
GWGD:=N<REF(N,1) AND REF(N,1)>=160 AND REF(N,1)>=REF(N,2);
风险:IF(GWGD,95,160),COLOR00ff00;

{以下设置副图显示方式}
100,COLORWHITE,POINTDOT;
STICKLINE(C,100,100,4,0),COLORWHITE;
STICKLINE(达标,50,100,4,0),COLOR0000FF;

引用:

{指标使用方法：
经典指标 K D J ，适当优化成新宠；
中线参考价值大，奥妙尽在浪形中。
预测信号是启动，涨停价位十来送；
涨幅跟踪好低吸，高位风险应慎重。}

引用:

公式名称: 空中加油
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2007-01-30
发表网址: http://www.li20.net/viewthread.php?tid=617910&highlight=

引用:

一品贺新春----【空中加油】



牛市就该选择牛股！2006年的股市，已经走了一年的牛市了，你还在找小虾米，还一直在波涛汹涌的大海边捡贝壳吗？适应牛市，骑上牛股，波段操作，操作最安全、获利空间最大！
在2007年春节即将来临之际,一品思考，努力编写指标{空中加油}，原码奉送，祝愿创幻所有朋友新春快乐,新年发财！

引用:

{一品【空中加油Z】----创幻论坛一品茶缘编写，大智慧主图指标}{飞弧通用}
{指标使用方法：
1、启动跑道可关注，航空飞机安全行；空中加油等买票，加速远航好收益！
2、启动时间长又长，航天飞机要远航！
3、启动时间长，均线越顺畅；航天飞机快，登上要坐好！}

MA5:MA(CLOSE,5);
MA10:MA(CLOSE,10);
MA20:MA(CLOSE,20);
MA30:MA(CLOSE,30);
MA250:MA(CLOSE,250),COLORRED;
N1:=BARSLAST(CROSS(MA5,MA10));
N2:=BARSLAST(CROSS(MA10,MA5));
多:=IF(N1<N2,N1+1,0);
空:=IF(N2<N1,N2+1,0);
QSXS:=MA5>MA20 AND MA10>MA20 AND MA20>REF(MA20,1) AND MA30>REF(MA30,1);
启动:=多*QSXS,COLORRED,LINETHICK0;
跑道:=空*QSXS,COLORFFFF00,LINETHICK0;
HKFJ:=HHV(多,5)>=2 AND QSXS AND MA5>REF(MA5,1) AND MA5>MA10;
航空飞机:=HKFJ*多,COLORFF00FF,LINETHICK2;
HKSJ:=BARSLAST(航空飞机>0 AND NOT(REF(航空飞机,1)))+1;
高度:=(C/REF(C,HKSJ)-1)*100,COLOR00FFFF;
空中加油:启动>0 AND 航空飞机=0,COLOR00FF00,POINTDOT,LINETHICK0;
N3:=BARSLAST(空中加油)+1;
K5:=ATAN((MA5/REF(MA5,1)-1)*100)*180/3.14159;
JXGD1:=K5>REF(K5,1) AND REF(K5,1)<REF(K5,2);
JXGD2:=MA5>REF(MA5,1) AND REF(MA5,1)<REF(MA5,2);
加速远航:FILTER((JXGD1 OR JXGD2) AND C>MA5 AND HKFJ,3),COLOR00FFFF,POINTDOT,LINETHICK0;
N4:=BARSLAST(加速远航);

{以下设置主图显示方式}
STICKLINE(空中加油,(O+C)/2-0.01,(O+C)/2+0.01,4,0),COLOR00FF00;
STICKLINE(空中加油,L,H,1,1),COLOR00FF00;
STICKLINE(加速远航,(O+C)/2-0.01,(O+C)/2+0.01,4,0),COLOR00FFFF;
STICKLINE(加速远航,L,H,1,1),COLOR00FFFF;
STICKLINE(N4>0 AND N4<=5,REF(O,N4+1),REF(O,N4+1),4,1),COLORFFFFFF;
DRAWTEXT(加速远航,L,'加▲速'),COLOR00FFFF;
DRAWTEXT(航空飞机,MA30,'○'),COLORFFFFFF;
DRAWTEXT(空中加油,MA30,'□'),COLOR00FF00;

引用:

{一品【空中加油】----创幻论坛一品茶缘编写，大智慧副图指标}{飞弧通用}
{指标使用方法：
1、启动跑道可关注，航空飞机安全行；空中加油等买票，加速远航好收益！
2、启动时间长又长，航天飞机要远航！
3、启动时间长，均线越顺畅；航天飞机快，登上要坐好！}

MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA20:=MA(CLOSE,20);
MA30:=MA(CLOSE,30);
MA250:=MA(CLOSE,250),COLORRED;
N1:=BARSLAST(CROSS(MA5,MA10));
N2:=BARSLAST(CROSS(MA10,MA5));
多:=IF(N1<N2,N1+1,0);
空:=IF(N2<N1,N2+1,0);
QSXS:=MA5>MA20 AND MA10>MA20 AND MA20>REF(MA20,1) AND MA30>REF(MA30,1);
启动:多*QSXS,COLORRED,LINETHICK0;
跑道:空*QSXS,COLORFFFF00,LINETHICK0;
HKFJ:=HHV(多,5)>=2 AND QSXS AND MA5>REF(MA5,1) AND MA5>MA10;
航空飞机:HKFJ*多,COLORFF00FF,LINETHICK2;
HKSJ:=BARSLAST(航空飞机>0 AND NOT(REF(航空飞机,1)))+1;
高度:(C/REF(C,HKSJ)-1)*100,COLOR00FFFF;
空中加油:启动>0 AND 航空飞机=0,COLOR00FF00,POINTDOT,LINETHICK0;
N3:=BARSLAST(空中加油)+1;
K5:=ATAN((MA5/REF(MA5,1)-1)*100)*180/3.14159;
JXGD1:=K5>REF(K5,1) AND REF(K5,1)<REF(K5,2);
JXGD2:=MA5>REF(MA5,1) AND REF(MA5,1)<REF(MA5,2);
加速远航:FILTER((JXGD1 OR JXGD2) AND C>MA5 AND HKFJ,3),COLOR00FFFF,POINTDOT,LINETHICK0;
N4:=BARSLAST(加速远航);

{以下设置副图显示方式}
STICKLINE(空中加油,0,启动/10+1,4,1),COLOR00FF00;
STICKLINE(N4>0 AND N4<=5,REF(启动,N4+1),REF(启动,N4+1),4,0),COLORFFFFFF;
DRAWTEXT(加速远航,启动,'▲'),COLOR00FFFF;

引用:

公式名称: 一品操盘+量能助手
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2006-12-25
发表网址: http://www.li20.net/viewthread.php?tid=591199&highlight=

引用:

圣诞小礼--一品操盘+量能助手（原码）



鉴于创幻朋友对于一品指标的厚爱，在此圣诞节日，元旦将至之际，再次优化一品两个副图指标--一品操盘+量能助手，并附上详细指标编写思路与使用方法，提供原码，作为圣诞小礼，送与支持、关心一品的朋友。

引用:

{一品操盘----一品茶缘优化经典指标系列--WR威廉指标，大智慧副图指标}{飞狐通用}
{指标编写思路:
1、一品操盘线=今日收盘价与5日最高价的差除以5日最高价与5日最低价的差；
2、一品操盘线以50为平衡、80强势、回落80而大于50为回调买点；
3、一品操盘线低于10超跌恐慌、等于0绝望（即今日收盘等于5日最低点），大于90向上攻击、等于100涨停（即今日收盘价等于5日最高点，不一定是涨幅的+10%)；
4、根据观察，“涨”字信号，基本就是股价上穿5日均线、5日均线即将拐头或者正好拐头的位置，这个正是很好的买点！因此可以确定：一品操盘指标很有参考价值！
5、优选设置：前有恐慌、后有涨信号，即表示前期股价经过大幅下跌，今日股价重新上穿5日均线，即将走强，此点设定为优选！这时一般都是新的波段好买点！优选信号出现在30日均线向上的目标股时，操作更加安全！
6、助涨设置：当股价处于涨、或者强的位置时，同时出现放量上涨现象，确定为放量助涨。
指标使用技巧：
1、买点1：选择优选信号买入，前期日K线组合波浪形态优美的优先；
2、买点2：前期一品操盘线基本处于50以下，形成圆弧底形态，今日重新出现涨字信号，日K线组合波浪形态明显；
3、买点3：前期一品操盘线长期处于50以上，近日连续回落，出现慌、绝信号，表示短线超跌，结合30日均线、股价下跌幅度，作为超跌买点（此点只能买跌、不能追涨！）；
4、卖点1：当股价不断拉升，达到一个波段时间5--7天后，连续出现强字信号，结合波段中阳组合，处于后面的强、攻信号可能就是高位卖点！指标以红色圆圈表示风险。
5、卖点2：股价经过连续拉升，一品操盘线长期处于50以上，达到一个波段时间5--7天后，出现回字信号，一般就是股价即将回落卖点！指标以“跑”字信号表示。}

引用:

{一品操盘----一品茶缘优化经典指标--WR威廉指标，大智慧副图指标}{飞狐通用}
{N：1，8，1；}
WR:=ABS(100-100*(HHV(HIGH,5)-CLOSE)/(HHV(HIGH,5)-LLV(LOW,5)));
IF(WR>0,WR,0),COLORYELLOW;
涨:CROSS(WR,50),POINTDOT,COLOR0000FF;
强:CROSS(WR,80),POINTDOT,COLORYELLOW;
回:CROSS(80,WR) AND WR>50,POINTDOT,COLORWHITE;
险:=COUNT(WR>60,7)>=5 AND WR>90;
跑:=COUNT(WR>60,7)>=5 AND CROSS(80,WR);
慌:WR<=10 AND WR>0,POINTDOT,COLOR00FF00;
绝:WR=0,POINTDOT,COLORFF6600;
买:REF(WR,1)<10 AND C>REF(C,1) AND C>O,POINTDOT,COLORWHITE;
攻:WR>=90 AND WR<100 OR (H=HHV(H,5) AND H/REF(C,1)>=1.05),POINTDOT,COLORFF00FF;
停:WR=100,POINTDOT,COLORRED;
优选:IF((涨 AND COUNT(WR<=10,6) AND REF(WR,1)>10)*100,100,50),COLORFF6666,LINETHICK2;
FLSZ:=V*N>REF(V,1) AND C>REF(C,1) AND C>O;
助涨:(涨 OR 强) AND FLSZ,POINTDOT,COLORFF00FF;
DRAWICON(优选=100,50,1);
{以下设置副图显示方式}
STICKLINE(WR>=50,50,WR,1,0),COLORWHITE;
STICKLINE(WR>=90 AND WR<100,100,95,4,0),COLORWHITE;
STICKLINE(WR=100,100,95,4,0),COLORFF00FF;
STICKLINE(WR<=10 AND WR>0,0,5,4,0),COLORWHITE;
STICKLINE(WR=0,0,5,4,0),COLORFF6600;
DRAWTEXT(涨,60,'涨'),COLOR0000FF;
DRAWTEXT(助涨,25,'▲'),COLORFF00FF;
DRAWTEXT(助涨,20,'‖'),COLORFF00FF;
DRAWTEXT(强,70,'强'),COLORYELLOW;
DRAWTEXT(回,50,'回'),COLORWHITE;
DRAWTEXT(险,100,'●'),COLOR0000FF;
DRAWTEXT(跑,100,'跑'),COLORFFFF00;
DRAWTEXT(慌,20,'慌'),COLOR00FF00;
DRAWTEXT(绝,20,'绝'),COLORWHITE;
DRAWTEXT(买,50,'买'),COLORWHITE;
DRAWTEXT(攻,50,'攻'),COLORFF00FF;
DRAWTEXT(停,85,'停'),COLOR0000FF;

50,COLORFFFF00,LINETHICK2;
10,COLOR00FF00;
90,COLOR00FF00;

引用:

{量能助手----一品茶缘编写，大智慧副图指标}{飞狐通用}

换手:V/CAPITAL*100, COLORWHITE;
V1:=V/CAPITAL*100;
V5:MA(V1,5);
V30:=MA(V1,30);
V60:=MA(V1,60);
V120:MA(V1,120);
V250:=MA(V1,250);
需量:MIN(V60*1.1,V250*1.1),COLOR0066FF;
突破:CROSS(换手,需量)*2,COLOR00FF00,LINETHICK2;
牛股:CROSS(换手,需量*2)*5,COLORYELLOW,LINETHICK2;
V金叉:=CROSS(V1,V30);
JCSJ:=BARSLAST(V金叉);
优选:(牛股 AND JCSJ<=2 AND (C/REF(C,1)-1)*100>=3)*8,COLORRED,LINETHICK2;
DRAWICON(优选,1,1);

引用:

公式名称: 均线拐点
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2006-10-24
发表网址: http://www.li20.net/viewthread.php?tid=547036&highlight=

引用:

简单点好----{均线拐点}主副图原码奉送



  2006年9月以来，在创幻发了一点DD，受到了创幻朋友的关心、支持，再次感谢！有感于股市的变幻莫测，有感于散户朋友的辛辛苦苦，有感于指标的繁杂难解……因此编写一个简单实用的波段指标{均线拐点}，并将原码奉送，便于所有朋友真正理解指标含义，应用于实战，希望大家喜欢。同时真诚欢迎朋友们提出优化意见！
    2006-10-24//22:10补充买点2

引用:

指标编写思路：
1、中线多头排列，安全操作；
2、短线多头排列、或近期曾经多头排列；
3、短期均线处于粘合状态（粘合间距默认为N--3%，龙头股可以适当调大）；
4、短期均线曾经回调至粘合状态；
5、当5日均线重新拐头向上时，即为新的波段买点。
指标测试成功率：2006年5天3%、10天5%、20天10%均在70%左右，不算高；但是相对安全，大波段基本能够抓住。

引用:

{均线拐点----一品茶缘编写，大智慧副图指标/飞狐通用}
{N:1,10,3;}
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
MA30:=MA(C,30);
MA60:=MA(C,60);
MA120:=MA(C,120);
短线多头:=MA5>MA10 AND MA10>MA20 AND MA20>MA30;
中线多头:=MA30>MA120 AND MA60>MA120;
均线粘合:=(HHV(MA5,HHV(MA10,MA20))/LLV(MA5,LLV(MA10,MA20))-1)*100<=N;
均线拐点:=COUNT(短线多头,10) AND COUNT(MA5<REF(MA5,1),3) AND MA5>REF(MA5,1);
XG:=中线多头 AND 均线粘合 AND 均线拐点 AND C>REF(C,1);
选股:XG AND NOT(REF(XG,1)),COLORYELLOW,linethick2;
均线粘合2:=(MAX(MA5,MAX(MA10,MA20))/MIN(MA5,MIN(MA10,MA20))-1)*100<=N;
XG2:=中线多头 AND 均线粘合2 AND 均线拐点 AND C>REF(C,1);
选股2:(XG2 AND NOT(REF(XG2,1)))*0.5,COLORWHITE,linethick2;

-----------------------------------------

{均线拐点Z----一品茶缘编写，大智慧主图指标/飞狐通用}
{N:1,10,3;}
MA5:MA(C,5);
MA10:=MA(C,10);
MA20:MA(C,20);
MA30:MA(C,30);
MA60:MA(C,60);
MA120:=MA(C,120);
短线多头:=MA5>MA10 AND MA10>MA20 AND MA20>MA30;
中线多头:=MA30>MA120 AND MA60>MA120;
均线粘合:=(HHV(MA5,HHV(MA10,MA20))/LLV(MA5,LLV(MA10,MA20))-1)*100<=N;
均线拐点:=COUNT(短线多头,10) AND COUNT(MA5<REF(MA5,1),3) AND MA5>REF(MA5,1);
XG:=中线多头 AND 均线粘合 AND 均线拐点 AND C>REF(C,1);
选股:=XG AND NOT(REF(XG,1));
均线粘合2:=(MAX(MA5,MAX(MA10,MA20))/MIN(MA5,MIN(MA10,MA20))-1)*100<=N;
XG2:=中线多头 AND 均线粘合2 AND 均线拐点 AND C>REF(C,1);
选股2:=XG2 AND NOT(REF(XG2,1)),COLORWHITE,linethick2;

{以下设置主图显示方式：}
STICKLINE(选股,h,l,0,1),COLORYELLOW,linethick2;
STICKLINE(选股,o,c,4,1),COLORYELLOW,linethick2;
DRAWTEXT(选股,L-0.1, '买'),COLORYELLOW;
STICKLINE(选股2,h,l,0,1),COLORWHITE,linethick2;
STICKLINE(选股2,o,c,4,1),COLORWHITE,linethick2;
DRAWTEXT(选股2,L-0.15, '买2'),COLORWHITE;

引用:

公式名称: 一品种树
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2006-11-28
发表网址: http://www.li20.net/viewthread.php?tid=573647&highlight=

引用:

短线波段----{一品种树}副图指标原码奉送



大盘开始进入调整区，一品懒得选股，闲逛创幻指标公式区，得一二思路，组合优化，拾得短线波段操作指标，稍加美化，名曰{一品种树}，并附指标使用方法说明。闲观尚可，实战尚需各位朋友各自多加揣摩，必将有所收益。一品无心之作，博高手一笑，还请朋友多多批评！哈哈^-^

特别提醒:本帖23楼有再次美化版本,信号一样,只是加了点背景色.附图可以比较.

引用:

{一品种树----一品茶缘编写，大智慧副图指标}{飞狐通用}
{指标使用方法说明：森林--操作线，不见绿色不操作；土壤--量能变化情况；森林白色背景--中期量能变化情况，向上最好；耕耘区--操作区；长叶--股价初涨区；开花--股价进入拉升区；结果--股价进入急拉区；}
AA:=(EMA(C,4)-EMA(C,7))/EMA(C,7)*4000;
森林:AA,COLOR00FF00,LINETHICK1;
量:=(EMA(IF(C>=REF(C,2),V,(-V)),34)/MA(V,34))*100;
X26:=EMA(量,26),COLORFF00FF;
STICKLINE(X26>=REF(X26,1),0,X26,5,0),COLORWHITE;
STICKLINE(X26<REF(X26,1),0,X26,5,0),COLORDDDDDD;
土壤:EMA(量,9),COLORFF6633,LINETHICK1;
TJ1:=AA>=REF(AA,1);
TJ2:=土壤>=REF(土壤,1);
TJ3:=X26>=REF(X26,1);
耕耘区:(TJ1+TJ2 +TJ3)>=2,COLORWHITE;
长叶:(耕耘区 AND COUNT(耕耘区,3)=1)*30,STICK,COLOR00FF00,LINETHICK5;
开花:(耕耘区 AND CROSS(AA,10))*50,STICK,COLORYELLOW,LINETHICK5;
结果:((TJ1+TJ2 +TJ3)=3 AND AA>=20 AND COUNT(AA>REF(AA,1),3)=1)*80,STICK,COLORFF00FF,LINETHICK5;
{以下设置副图显示方式}
IF(AA>=0, AA, 5),COLOR00FF00,LINETHICK2;
IF(AA<0, AA, 5),COLORFF6600,LINETHICK2;
STICKLINE(X26>=REF(X26,1), X26, X26,8,0),COLORRED,LINETHICK1;
STICKLINE(X26<REF(X26,1), X26, X26,8,0),COLORWHITE,LINETHICK1;
STICKLINE(耕耘区,-5,5,4,1),COLORWHITE,LINETHICK1;
STICKLINE((TJ1+TJ2 +TJ3)=3,-5,5,4,1),COLOR00FF00,LINETHICK1;
DRAWTEXT(长叶,50,'长叶'),COLOR00FF00;
DRAWTEXT(开花,80,'赏花'),COLORYELLOW;
DRAWTEXT(结果,100,'摘果'),COLOR0000FF;
0,COLORWHITE;

引用:

公式名称: 颠倒黑白
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2006-11-09
发表网址: http://www.li20.net/viewthread.p ... B%C6%B7%B2%E8%D4%B5

引用:

黑马回头----{颠倒黑白}主副图指标原码



{颠倒黑白----一品茶缘编写，大智慧主图、副图指标}{飞狐通用}
指标编写思路：
1、趋势向上：30日均线保持向上，安全操作；
2、黑马界定：连续三天大幅拉升，阶段涨幅较大（参数ZF1）；
3、白马界定：四天内至少有三天拉升，阶段涨幅较大（参数ZF1）；
4、黑白买点：以黑马、白马起涨的第一天收盘价为支撑点，设为黑、白买点；
5、买点1、2：当股价在10天内重新回落到黑白买点时，分别设定为买点1、买点2。
6、信号过滤：当买点信号第一次出现后，并有反弹超过黑白买点后，此后买点过滤。
7、奔马界定：5日均线连续5天(参数N)以上向上运行，且短期均线多头排列，确定为奔马；
8、奔马饮水：奔马最后确认的5日内，5日均线回头，且日线收盘位于10日均线与30日均线之间，短线趋势向上不变，设定为奔马饮水；此时股价一般是第一波拉升建仓后的洗盘买点。

指标使用技巧：
1、清楚反弹：该指标为寻找大幅拉升龙头的回调买点，一般只是反弹行情，期望值不可过高；
2、短期优选：买点信号离黑马、白马信号时间越短越好；
3、趋势优选：买点股价依然保持在30日均线支撑附近，优选。
4、盘中把握：买点设定为黑白买点，盘中股价打到黑白买点位置即会出现低买信号，---注意尽量买在黑白买点附近，盘中切记不可追涨！
5、饮水判断：如前期已经有饮水信号出现，说明短期内股价已经明显出现多个拉升波段，此时的回调也许会变成破位走弱，应该适当回避。

名称来源：一品认为，做股票重在顺势而为，即买在股票波段的起涨点，只做拉升段最好。但是许多朋友对拉升段的判断又难以把握，因此，拉升后的回调、反弹行情，也许可以成为我们的一点补充----当然，这已经与顺势而为的思路相背离了。因此本该是黑马回头的指标，一品命名为：{颠倒黑白}！呵呵^-^

引用:

{颠倒黑白----一品茶缘编写，大智慧副图指标}{飞狐通用}
{ZF1:5,30,15;ZF2:1,10,3;N:1,10,1;}
QSXS:=MA(C,30)>=REF(MA(C,30),1);
ZF:=(C/REF(C,1)-1)*100;
黑马:((C/ref(C,3)-1)*100>=ZF1 and count(ZF>=ZF2,3)=3 AND QSXS)*15,COLORFF00FF,LINETHICK2;
HMSJ:=BARSLAST(黑马);
黑:IF(HMSJ<=10 AND QSXS,REF(C,HMSJ+2),0),COLORFF6600,POINTDOT,LINETHICK2;
DM1:=LOW<=REF(C,HMSJ+2) AND HMSJ<=10 AND 黑马=0;
GL1:=黑>0 AND CROSS(C,黑);
低买1:(DM1>0 AND COUNT(GL1,HMSJ)=0)*黑,COLOR00FF00,LINETHICK2;
白马:((H/ref(L,4)-1)*100>=ZF1 and count(ZF>=ZF2,4)>=3 AND H=HHV(H,3) AND QSXS)*10,COLORYELLOW,STICK,LINETHICK5;
BMSJ:=BARSLAST(白马);
白:IF(BMSJ<=10 AND QSXS,REF(C,BMSJ+3),0),COLORWHITE,POINTDOT,LINETHICK2;
DM2:=LOW<REF(C,BMSJ+3) AND BMSJ<=10 AND 白马=0;
GL2:=白>0 AND CROSS(C,白);
低买2:(DM2>0 AND COUNT(GL2,BMSJ)=0)*白,COLORWHITE,LINETHICK2;
MA5:=MA(C,5);
MA10:=MA(C,10);
MA20:=MA(C,20);
MA30:=MA(C,30);
BM:=COUNT(MA5>REF(MA5,1),N)=N AND MA5>MA10 AND MA10>MA20 AND MA20>MA30;
奔马:BM*5,COLOR0000FF,POINTDOT,LINETHICK2;
STICKLINE(奔马>0,0 ,5 ,5 ,1 ),color0000FF;
BMSJ2:=BARSLAST(奔马);
BMHT:=MA5<REF(MA5,1) AND C<MA5 AND C<MA10 AND C>MA30;
饮水:(BMSJ2<=5 AND BMHT AND QSXS)*3,COLORFF6600,LINETHICK2;

引用:

颠倒黑白Z----一品茶缘编写，大智慧主图指标}{飞狐通用}
{ZF1:5,30,15;ZF2:1,10,3;N:1,10,1;}
MA5:MA(C,5),COLORWHITE,LINETHICK2;
MA10:MA(C,10),COLORYELLOW,LINETHICK1;
MA20:MA(C,20),COLORFF00FF,LINETHICK1;
MA30:MA(C,30),COLORRED,LINETHICK2;
QSXS:=MA(C,30)>=REF(MA(C,30),1);
ZF:=(C/REF(C,1)-1)*100;
黑马:=((c/ref(c,3)-1)*100>=ZF1 and count(ZF>=ZF2,3)=3 AND QSXS)*15,COLORFF00FF,LINETHICK2;
HMSJ:=BARSLAST(黑马);
黑:IF(HMSJ<=10 AND QSXS,REF(C,HMSJ+2),0),COLORFF6600,POINTDOT,LINETHICK2;
DM1:=LOW<=REF(C,HMSJ+2) AND HMSJ<=10 AND 黑马=0;
GL1:=黑>0 AND CROSS(C,黑);
低买1:=(DM1>0 AND COUNT(GL1,HMSJ)=0)*黑,COLOR00FF00,LINETHICK2;
白马:=((H/ref(l,4)-1)*100>=ZF1 and count(ZF>=ZF2,4)>=3 AND H=HHV(H,3) AND QSXS)*10,COLORYELLOW,STICK,LINETHICK5;
BMSJ:=BARSLAST(白马);
白:IF(BMSJ<=10 AND QSXS,REF(C,BMSJ+3),0),COLORWHITE,POINTDOT,LINETHICK2;
DM2:=LOW<REF(C,BMSJ+3) AND BMSJ<=10 AND 白马=0;
GL2:=白>0 AND CROSS(C,白);
低买2:=(DM2>0 AND COUNT(GL2,BMSJ)=0)*白,COLORWHITE,LINETHICK2;
BM:=COUNT(MA5>REF(MA5,1),N)=N AND MA5>MA10 AND MA10>MA20 AND MA20>MA30;
奔马:=BM*5,COLOR0000FF,POINTDOT,LINETHICK2;
{STICKLINE(奔马>0,0 ,5 ,5 ,1 ),color0000FF;}
BMSJ2:=BARSLAST(奔马);
BMHT:=MA5<REF(MA5,1) AND C<MA5 AND C<MA10 AND C>MA30;
饮水:=(BMSJ2<=5 AND BMHT AND QSXS)*3,COLORFF6600,LINETHICK2;
{以下设置主图显示方式}
STICKLINE(白马,h,l,0,1),colorYELLOW,linethick2;
STICKLINE(白马,o,c,4,1),colorYELLOW,linethick2;
STICKLINE(黑马,h,l,0,1),colorFF00FF,linethick2;
STICKLINE(黑马,o,c,4,1),colorFF00FF,linethick2;
DRAWTEXT(奔马>0 ,MA30-0.02 , '○'),coloryellow;
STICKLINE(饮水,h,l,0,1),color00FF00,linethick2;
STICKLINE(饮水,o,c,4,1),color00FF00,linethick2;
DRAWTEXT(低买1>0 ,L*0.99 , '◆'),COLOR00FF00,LINETHICK1;
DRAWTEXT(低买2>0 ,L*0.99 , '□'),COLORWHITE,LINETHICK1;

引用:

公式名称: 秘密买点
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2006-09-28
发表网址: http://www.li20.net/viewthread.p ... B%C6%B7%B2%E8%D4%B5

引用:

国庆小礼--{秘密买点---主\副图指标一套奉送}



    继一品茶缘原创精品指标{三浪启动--主、副图指标一套奉送}、{短线快马主图、副图}原码奉送之后，第三套原创买卖提示指标{秘密买点----主\副图指标一套}再次作为国庆、中秋礼物，原码奉送，欢迎热心支持的各位朋友试用，同时欢迎您提出宝贵意见！

引用:

{秘密买点----一品茶缘编写，大智慧副图指标}{飞狐通用}
{N:5,250,14;}
K:=N/2;
DTPL:=MA(C,N)>MA(C,N*1.5) AND MA(C,N*1.5)>MA(C,N*3) AND MA(C,3)>MA(C,N*6);
选择均线:N,POINTDOT,COLORYELLOW;
强弱天数:K,POINTDOT,COLORFF00FF;
连续走强:=COUNT(C>MA(C,N),K)=K;
ZQSJ:=BARSLAST(连续走强);
STICKLINE(连续走强 ,0 ,K*0.3 ,5 ,1 ),colorYELLOW;
下穿:=CROSS(MA(C,N),C);
GL:=MA(C,N/2)/MA(C,N*2)>=1.05;
买跌:(下穿 AND ZQSJ<=3 AND DTPL AND GL)*N,COLOR00FF00,LINETHICK2;
连续走弱:=COUNT(C<MA(C,N),K)=K;
ZRSJ:=BARSLAST(连续走弱);
STICKLINE(连续走弱 ,0 ,K*-0.3 ,5 ,1 ),color00FF00;
上穿:=CROSS(C,MA(C,N));
买涨:(上穿 AND ZRSJ<=3)*K,COLORFF00FF,LINETHICK2;
强:连续走强*K*0.3,colorYELLOW;
弱:连续走弱*K*-0.3,color00FF00;

-----------------------------------------------

{秘密买点z----一品茶缘编写，大智慧主图指标}{飞狐通用}
{N:5,250,14;}
K:=N/2;
MAK:MA(CLOSE,K),COLORWHITE,LINETHICK2;
MAN:MA(CLOSE,N),COLORYELLOW,LINETHICK2;
DTPL:=MA(C,N)>MA(C,N*1.5) AND MA(C,N*1.5)>MA(C,N*3) AND MA(C,3)>MA(C,N*6);
选择均线:=N,POINTDOT,COLORYELLOW;
强弱天数:=K,POINTDOT,COLORFF00FF;
连续走强:=COUNT(C>MA(C,N),K)=K;
ZQSJ:=BARSLAST(连续走强);
{STICKLINE(连续走强 ,0 ,K*0.3 ,5 ,1 ),colorYELLOW;}
下穿:=CROSS(MA(C,N),C);
GL:=MA(C,N/2)/MA(C,N*2)>=1.05;
买跌:=(下穿 AND ZQSJ<=3 AND DTPL AND GL)*N,COLOR00FF00,LINETHICK2;
连续走弱:=COUNT(C<MA(C,N),K)=K;
ZRSJ:=BARSLAST(连续走弱);
{STICKLINE(连续走弱 ,0 ,K*-0.3 ,5 ,1 ),color00FF00;}
上穿:=CROSS(C,MA(C,N));
买涨:=(上穿 AND ZRSJ<=3)*K,COLORFF00FF,LINETHICK2;

{以下设置显示方式：}
DRAWTEXT(买涨>0 ,L*0.99 , '●'),colorYELLOW,LINETHICK1;
STICKLINE(买涨>0,h,l,0,1),colorYELLOW,linethick2;
STICKLINE(买涨>0,o,c,4,1),colorYELLOW,linethick2;
DRAWTEXT(买跌>0 ,L*0.99 , '◆'),COLOR00FF00,LINETHICK1;
STICKLINE(买跌>0 ,h,l,0,1),COLOR00FF00,linethick2;
STICKLINE(买跌>0 ,o,c,4,1),COLOR00FF00,linethick2;
DRAWTEXT(连续走强>0 ,MAN-0.01 , '○'),colorYELLOW,LINETHICK1;
DRAWTEXT(连续走弱>0 ,MAK-0.01 , '○'),color00FF00,LINETHICK1;