引用:

公式名称: 获利操盘
适用软件: 大智慧L2
发 表 人: 一品茶缘     
发表日期: 2008-02-08
发表网址: http://www.chcj.net/redirect.php ... 224&ptid=958542

引用:

在2008新春之际,查阅论坛帖子,偶见befe-1先生提供基础指标与使用方法,思路不错,再次修改为能够自动提示的解盘指标,并简化文字说明,便于判断,仅为新年礼物送给大家,祝愿所有朋友新春快乐,新年发财,多多获利!

自动提示----【获利操盘】


{获利操盘----创幻论坛一品茶缘修改优化，大智慧L-2主、副图指标}
{感谢创幻论坛befe-1先生提供原创思路}
{获利操盘指标使用方法：
上穿底部先关注，突破红线请买入；
穿卖冲顶拉升急，跌破顶线清仓出。}

现价:C;
底部: COST(5),COLORYELLOW;
买入: COST(30),COLORRED;
卖出: COST(75),COLORGREEN;
顶部: COST(95),COLORFF00FF;
AA:=BARSLAST(CROSS(C,COST(5)));
AA2:=BARSLAST(CROSS(COST(5),C));
BB:=BARSLAST(CROSS(C,COST(30)));
BB2:=BARSLAST(CROSS(COST(30),C));
CC:=BARSLAST(CROSS(C,COST(75)));
CC2:=BARSLAST(CROSS(COST(75),C));
DD:=BARSLAST(CROSS(C,COST(95)));
DD2:=BARSLAST(CROSS(COST(95),C));
底部关注:=BETWEEN(C,COST(5),COST(30)) AND AA<AA2 AND AA<BB2;
开始建仓:=BETWEEN(C,COST(30),COST(75)) AND BB<BB2 AND BB<CC2;
拉升待涨:=BETWEEN(C,COST(75),COST(95)) AND CC<CC2 AND CC<DD2;
冲顶阶段:=C>=COST(95) AND DD<DD2;
破顶减仓:=BETWEEN(C,COST(95),COST(75)) AND DD>DD2 AND CC>DD2;
走弱出局:=BETWEEN(C,COST(75),COST(30)) AND CC>CC2 AND BB>CC2;
弱市观望:=BETWEEN(C,COST(30),COST(5)) AND BB>BB2 AND AA>BB2;
赶底不碰:=C<=COST(5) AND AA>AA2;
{以下设置解盘显示文字}
DRAWFLAGTEXT(底部关注,COST(50),'▲股价见底，开始关注！'),COLORFFFFFF;
DRAWFLAGTEXT(开始建仓,COST(50),'■股价走强，开始建仓！'),COLOR00FFFF;
DRAWFLAGTEXT(拉升待涨,COST(50),'★股价拉升，持股待涨！'),COLOR0000FF;
DRAWFLAGTEXT(冲顶阶段,COST(50),'●冲顶阶段，注意风险！'),COLORFF00FF;
DRAWFLAGTEXT(破顶减仓,COST(50),'□股价破顶，开始减仓！'),COLOR00FF00;
DRAWFLAGTEXT(走弱出局,COST(50),'◇股价走弱，清仓出局！'),COLOR00FF00;
DRAWFLAGTEXT(弱市观望,COST(50),'△弱市区域，观望为宜！'),COLORFFFF00;
DRAWFLAGTEXT(赶底不碰,COST(50),'○股价赶底，暂时不碰！'),COLORFFFF00;

引用:

{获利操盘----创幻论坛一品茶缘修改优化，通用版本副图指标,简化备用}
{感谢创幻论坛befe-1先生提供原创思路}
{获利操盘指标使用方法：
上穿底部先关注，突破红线请买入；
穿卖冲顶拉升急，跌破顶线清仓出。}

现价:C,COLORFFFFFF;
底部: COST(5),COLORYELLOW;
买入: COST(30),COLORRED;
卖出: COST(75),COLORGREEN;
顶部: COST(95),COLORFF00FF;
AA:=BARSLAST(CROSS(C,COST(5)));
AA2:=BARSLAST(CROSS(COST(5),C));
BB:=BARSLAST(CROSS(C,COST(30)));
BB2:=BARSLAST(CROSS(COST(30),C));
CC:=BARSLAST(CROSS(C,COST(75)));
CC2:=BARSLAST(CROSS(COST(75),C));
DD:=BARSLAST(CROSS(C,COST(95)));
DD2:=BARSLAST(CROSS(COST(95),C));
关注:BETWEEN(C,COST(5),COST(30)) AND AA<AA2 AND AA<BB2,COLORFFFFFF;
建仓:BETWEEN(C,COST(30),COST(75)) AND BB<BB2 AND BB<CC2,COLOR00FFFF;
拉升:BETWEEN(C,COST(75),COST(95)) AND CC<CC2 AND CC<DD2,COLOR0000FF;
冲顶:C>=COST(95) AND DD<DD2,COLORFF00FF;
减仓:BETWEEN(C,COST(95),COST(75)) AND DD>DD2 AND CC>DD2,COLOR00FF00;
出局:BETWEEN(C,COST(75),COST(30)) AND CC>CC2 AND BB>CC2,COLORFFFFFF;
弱市:BETWEEN(C,COST(30),COST(5)) AND BB>BB2 AND AA>BB2,COLORFFFF00;
赶底:C<=COST(5) AND AA>AA2,COLORFF6600;

引用:

公式名称: 爱大波
适用软件: 大智慧L2
发 表 人: 一品茶缘     
发表日期: 2008-02-17
发表网址: http://www.chcj.net/redirect.php ... 199&ptid=958542

引用:

偶见论坛图片帖子,回想{抓大波}指标,适当简化\优化成{爱大波},送给喜欢的朋友:

{爱大波----创幻一品简化一线主图,大智慧L-2变色线}
{N：50;100;85;N:表示获利盘要求;}
{爱大波指标编写思路：
其实就是对于股价获利盘的要求，获利盘高的目标，往往处于拉升段；
指标使用方法：线上操盘，线下休息，只做主升浪！}
AA:EMA(COST(N),10),COLORFFFFFF,LINETHICK2;
PARTLINE(AA,AA>REF(AA,1),RGB(255,0,0),AA<REF(AA,1),RGB(0,255,0),AA=REF(AA,1),RGB(255,255,0)),LINETHICK2;
{IF(AA>=REF(AA,1),AA, AA*0.99),COLOR0000FF,LINETHICK2;大智慧1版本用此行代替变色线}

引用:

公式名称: 急跌警报
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2008-04-01
发表网址: http://www.chcj.net/redirect.php ... 84&ptid=958542]

引用:

大盘跌跌不休，个股何时见底？就连{一品抄底}指标也有不少失手之处。针对现在市场，提供短线急跌警报指标，仅供参考。可以配合{一品抄底}使用。


{急跌警报---创幻论坛一品茶缘编写，通用副图指标}
{急跌警报指标使用说明：
跌跌不休何时底，警报声声提醒你；
急跌出现可低吸，反弹小利先休息。}
MA1:=(H+L+C+O)/4;
MA5:=MA(MA1,5);
PL:=(MA1/MA5-1)*100;
警报:IF(PL<=-10,0-PL-10,0),COLORSTICK;
急跌:PL<=-12,COLOR00FF00;

[ 本帖最后由 蓝鼠 于 2008-5-2 10:51 编辑 ]

引用:

公式名称: 暴涨暴跌
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2008-05-02
发表网址: http://www.chcj.net/redirect.php ... 40&ptid=958542]

引用:

五一小礼:跟踪龙头----暴涨暴跌
祝所有朋友五一节日快乐!


{暴涨暴跌---创幻论坛一品茶缘编写，通用副图指标}
{N:5,10,8;}
{暴涨暴跌指标使用说明：
领涨领跌是龙头，积极跟踪有收获；
暴涨疯狂防风险，暴跌出现可春播！}
ZF:=(C/REF(C,1)-1)*100;
ST:=ABS(C/O-1)*100;
ZF3:SUM(ZF,3),COLORFFFFFF,POINTDOT,LINETHICK0;
领涨:IF(ZF>=N AND ST>=4,8,0),COLOR0000FF,POINTDOT,LINETHICK0;
暴涨:IF(SUM(ZF,3)>=18 OR SUM(ZF,4)>=18,18,0),COLORFF00FF,LINETHICK2;
领跌:IF(ZF<=0-N AND ST>=4,-8,0),COLORFFFF00,POINTDOT,LINETHICK0;
暴跌:IF(SUM(ZF,3)<=-18 OR SUM(ZF,4)<=-18,-18,0),COLOR00FF00,LINETHICK2;
STICKLINE(领涨,0,8,4,0),COLOR0000FF;
STICKLINE(领跌,0,-8,4,0),COLORFFFF00;

引用:

公式名称: 反向K线
适用软件: 通用
发 表 人: 一品茶缘     
发表日期: 2008-05-25
发表网址: http://www.chcj.net/redirect.php ... 31&ptid=958542]

引用:

见到有朋友喜欢逆向思维,也曾经见到飞弧版本的{反K线}指标;但考虑到其他软件的需要,现一品临时改编一个通用版本的{反向K线}副图,指标并没什么新意,仅送给喜欢逆向思维的朋友观察\思考:


{反向K线----创幻论坛一品茶缘编写，通用副图指标}
C1:REVERSE(C),COLORFFFFFF,POINTDOT,LINETHICK0;
O1:=REVERSE(O);
H1:=REVERSE(L);
L1:=REVERSE(H);
MA5:MA(C1,5);
MA10:MA(C1,10);
MA20:MA(C1,20);
MA30:MA(C1,30);
STICKLINE(C1<=O1,O1,C1,4,0),COLOR00FF00;
STICKLINE(C1<=O1,H1,L1,1,0),COLOR00FF00;
STICKLINE(C1>O1,O1,C1,4,0),COLOR0000FF;
STICKLINE(C1>O1,H1,L1,1,0),COLOR0000FF;